P11 - Temporizador com LCD Keypad Shield e Arduino: GUILHERME VENTURA, TALLYS CARLYSON DA SILVA, THIAGO MAYCON VILELA DA SILVA e VICTOR RODRIGUES ADABBO.
Deus criou os céus e a terra no princípio. E as pessoas criaram relógios de cozinha digitais como este. As pessoas decidiram criar uma substituição mais empolgante para o conceito original. Disseram: "Vamos construir algo melhor!"
A voz do povo chamou Deus, e Ele criou o Arduino. Agora, pessoas em todos os lugares têm Arduinos espalhados por seus continentes. Este foi um resultado positivo. As pessoas melhoraram este cronômetro de cozinha usando um Arduino.
Deus viu o novo timer de cozinha e achou horrível, mas engraçado. E isso é bom.
O datasheet da placa Arduino UNO R3 está disponível em: Manual Arduino® UNO R3.
Iremos criar um timer de cozinha controlado por Arduino. Este projeto ajudará você a gerenciar os tempos de cozimento desejados e evitar que os pratos cozinhem demais.
Você pode definir convenientemente um limite de tempo para o seu prato cozinhar e ficar afastado até ouvir o sinal sonoro do timer.
Usaremos um Shield de Teclado LCD Arduino neste projeto. Começaremos conectando o pequeno buzzer que colocará o dispositivo em funcionamento. Isso não deve levar mais do que alguns minutos, devido às capacidades de entrada e saída do shield, que são feitas através de sua interface de botões e LCD, respectivamente.
O manual com diagrama elétrico da placa do LCD KeyPad Shield está disponìvel em: LCD Keypad Shield .
Fluxo da interface do usuário do temporizador de cozinha:
- Após ligar, o dispositivo exibirá a mensagem “Arduino Kitchen Timer” por 3 segundos.
- O timer solicitará que você defina o tempo. Você pode mover o cursor para minutos e horas pressionando as teclas direita e esquerda.
- Você pode ajustar as configurações de minutos e horas com as teclas de seta para cima e para baixo.
- Depois de definir o tempo desejado, pressione o botão de seleção e o timer será iniciado.
- Se quiser definir a hora novamente, pressione o botão de seleção uma segunda vez.
- Quando o tempo terminar, a campainha emitirá um sinal sonoro.
- Para parar a campainha, pressione o botão de reinicialização no Keypad Shield.
Componentes necessários para o cronômetro de cozinha
- Arduino
- LCD Keypad Shield
- Campainha
Diagrama de circuito para o temporizador de cozinha
Primeiro, alinhe e coloque LCD Keypad Shield diretamente no Arduino. Em seguida, conecte o lado positivo do buzzer ao pino 12 do Arduino e o lado negativo do buzzer ao terra.
Código do projeto do temporizador de cozinha Arduino
Copie e carregue o código abaixo no Arduino IDE. Cada seção do código tem uma explicação para ajudar você a entender sua função.
#include <LiquidCrystal.h>
// select the pins used for the LCD keypad
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
// define some variables
int lcd_key = 0;
int adc_key_in = 0;
int hrs = 0;
int mins = 0;
int set_mins = 0;
int set_hrs = 1;
int secs = 60;
int cursor_pos = 1;
int buzzer_pin = 12;
bool startTimer = false;
bool setTimer = true;
bool get_time = false;
unsigned long interval=1000; // the time we need to wait
unsigned long previousMillis=0; // millis() returns an unsigned long.
// Defining button used by the lcd keypad
#define btnRIGHT 0
#define btnUP 1
#define btnDOWN 2
#define btnLEFT 3
#define btnSELECT 4
#define btnNONE 5
// read the buttons
int read_LCD_buttons()
{
adc_key_in = analogRead(0); // reading the button value from the lcd keypad
// checking which button is pressed
if (adc_key_in > 1000) return btnNONE; // We make this the 1st option for speed reasons since it will be the most likely result
if (adc_key_in < 50) return btnRIGHT;
if (adc_key_in < 250) return btnUP;
if (adc_key_in < 450) return btnDOWN;
if (adc_key_in < 650) return btnLEFT;
if (adc_key_in < 850) return btnSELECT;
return btnNONE; // when all others fail, return this...
}
void setup()
{
Serial.begin(115200);
pinMode(buzzer_pin, OUTPUT);
lcd.begin(16, 2); // start communication with LCD keypad shield
lcd.setCursor(0,0);
lcd.print("Arduino Kitchen");
lcd.setCursor(0, 1);
lcd.print(" Timer");
delay(3000);
}
void loop(){
// Checking which condition is true based on the button pressed
if(startTimer == true){
start_timer();
}
else if (setTimer == true){
set_timer();
}
}
// This function will count the time and will beep the buzzer when the time will be up.
void start_timer(){
// Checking whether time is up or not
if(hrs == 0 && mins == 0 && secs == 0){
lcd.setCursor(0, 0);
lcd.print(" Time is UP");
lcd.setCursor(0, 1);
lcd.print(" Beep Beep");
digitalWrite(buzzer_pin, HIGH);
delay(500);
digitalWrite(buzzer_pin, LOW);
delay(500);
}
else if(secs < 0){
secs = 59;
mins = mins - 1;
}
else if(mins < 0){
mins = 59;
hrs = hrs - 1;
}
else
{
get_time = true;
counter();
lcd.setCursor(0, 0);
lcd.print("Timer is ON");
lcd.setCursor(0, 1);
lcd.print(hrs);
lcd.print(":");
lcd.setCursor(4, 1);
lcd.print(mins);
lcd.print(":");
lcd.setCursor(8, 1);
lcd.print(secs);
}
lcd_key = read_LCD_buttons(); // read the buttons
switch (lcd_key) // depending on which button was pushed, we perform an action
{
// if select button is pressed, move back to set time
case btnSELECT:
{
startTimer = false;
setTimer = true;
delay(300);
lcd.clear();
break;
}
case btnNONE:
{
break;
}
}
}
// This function will set the time
void set_timer(){
counter();
lcd.setCursor(0, 0);
lcd.print("Set Time");
lcd.setCursor(0, 1);
lcd.print("Hrs:");
lcd.print(hrs);
lcd.setCursor(8, 1);
lcd.print("Mins:");
lcd.print(mins);
lcd.setCursor(0,1);
lcd_key = read_LCD_buttons(); // read the buttons
switch (lcd_key) // depending on which button was pushed, we perform an action
{
// if right button is pressed, then move the cursor to minutes
case btnRIGHT:
{
cursor_pos = set_mins;
break;
}
// if left button is pressed, then move the cursor to hours
case btnLEFT:
{
cursor_pos = set_hrs;
break;
}
// if up button is pressed, add 1 to the minutes or hours
case btnUP:
{
delay(300);
if(cursor_pos == set_mins){
mins++;
if(mins > 59){
mins = 0;
}
}
else if(cursor_pos == set_hrs){
hrs++;
if(hrs > 24){
hrs = 0;
}
}
break;
}
// if down button is pressed, minus 1 from the minutes or hours
case btnDOWN:
{
delay(300);
if(cursor_pos == set_mins){
mins--;
if(mins < 0){
mins = 60;
}
}
else if(cursor_pos == set_hrs){
hrs--;
if(hrs < 0){
hrs = 24;
}
}
break;
}
// if select button is pressed, start the timer
case btnSELECT:
{
startTimer = true;
setTimer = false;
mins = mins - 1;
delay(300);
break;
}
case btnNONE:
{
break;
}
}
}
void counter() {
unsigned long currentMillis = millis(); // grab current time
// check if "interval" time has passed (1000 milliseconds)
if ((unsigned long)(currentMillis - previousMillis) >= interval) {
lcd.clear();
if(get_time == true){
secs--;
get_time = false;
}
previousMillis = millis();
}
}Você criou seu próprio timer de cozinha! A melhor parte deste projeto é a possibilidade de adaptar este módulo para construir outros projetos que exijam uma interface simples entre um LCD e um botão ou campainha.
Referência: Muhammad Aqib
© Direitos de autor. 2025: Gomes; Sinésio Raimundo. Última atualização: 20/06/2025
Nenhum comentário:
Postar um comentário